floof/lib/floof.ex

defmodule Floof do
  @moduledoc """
  Documentation for `Floof`.
  """

  require Logger

  def accept(port, opts \\ []) do
    {:ok, socket} =
      :gen_tcp.listen(
        port,
        [
          :binary,
          packet: 4,
          active: false,
          reuseaddr: true
        ] ++ opts
      )

    Logger.info("Accepting connections on #{port}")
    loop_acceptor(socket)
    :ok = :gen_tcp.close(socket)
  end

  defp loop_acceptor(socket) do
    {:ok, client} = :gen_tcp.accept(socket)

    {:ok, pid} =
      Task.Supervisor.start_child(Floof.TaskSupervisor, fn ->
        serve(client, %{}, nil)
        :ok = :gen_tcp.close(client)
      end)

    :ok = :gen_tcp.controlling_process(client, pid)
    # switch to active now that we handed over the client
    :inet.setopts(client, [{:active, true}])
    Floof.Distributor.register(pid)
    loop_acceptor(socket)
  end

  def connect(host, port, sesskey \\ nil) do
    {:ok, socket} =
      :gen_tcp.connect(host, port,
        packet: 4,
        active: true
      )

    Floof.Distributor.register(self())
    Logger.info("Established connection to #{inspect(host)}:#{port}")

    if sesskey != nil do
      {:ok, encd} = :FloofProtocol.encode(:ProtoMessage, {:session, {:attach, sesskey}})
      :ok = :gen_tcp.send(socket, encd)
    end

    serve(socket, %{}, nil)
    :ok = :gen_tcp.close(socket)
  end

  defp serve(client, backlog, sesskey) do
    receive do
      {:tcp, _, message} ->
        message =
          if :erlang.is_binary(message) do
            message
          else
            :erlang.list_to_binary(message)
          end

        {:ok, dcd} = :FloofProtocol.decode(:ProtoMessage, message)
        backlog = handle_incoming(client, backlog, dcd)
        serve(client, backlog, sesskey)

      {:fwdxfer, {dcdhash, dcd}} ->
        :ok = send_summary(client, :requestpull, [dcdhash])
        serve(client, Map.put(backlog, dcdhash, dcd), sesskey)

      {:SessionPushed, key} ->
        {backlog, added_hashs} = extract_backlog(key, backlog, MapSet.new())
        :ok = send_summary(client, :requestpull, added_hashs)
        serve(client, backlog, key)

      {:tcp_closed, _} ->
        # put all the backlogged stuff back if possible
        if sesskey != nil do
          for item <- backlog do
            Floof.SessionManager.push(sesskey, item)
          end

          Floof.SessionManager.deattach(sesskey, self())
        end

      x ->
        Logger.warn("unable to handle request: #{inspect(x)}")
        serve(client, backlog, sesskey)
    end
  end

  defp handle_incoming(client, backlog, dcd) do
    Logger.debug("got packet #{inspect(dcd)}")

    case dcd do
      {:session, {:attach, key}} ->
        Floof.Distributor.register_key(key, self())

        if Floof.SessionManager.attach(key, self()) do
          send(self(), {:SessionPushed, key})
        end

        backlog

      {:summary, {:Summary, direction, hashes}} ->
        case direction do
          :requestpull ->
            {to_pull, to_drop} = partition_hashes(hashes)

            if not Enum.empty?(to_pull) do
              :ok = send_summary(client, :pull, to_pull)
            end

            if not Enum.empty?(to_pull) do
              :ok = send_summary(client, :drop, to_drop)
            end

            backlog

          :pull ->
            for mhash <- hashes do
              case Map.fetch(backlog, mhash) do
                {:ok, item} ->
                  {:ok, encd} = :FloofProtocol.encode(:ProtoMessage, {:xfer, item})
                  :ok = :gen_tcp.send(client, encd)

                :error ->
                  nil
              end
            end

            backlog

          :drop ->
            Map.drop(backlog, hashes)
        end

      {:xfer, xf} ->
        mhash = Floof.Message.emit(xf)
        # notify the remote end that we successfully consumed the message
        # non-fatal if this fails
        send_summary(client, :drop, [mhash])
        backlog
    end
  end

  defp extract_backlog(key, backlog, added_ids) do
    case Floof.SessionManager.pop(key) do
      :empty ->
        {backlog, added_ids}

      {:value, {mhash, entry}} ->
        extract_backlog(key, Map.put(backlog, mhash, entry), MapSet.put(added_ids, mhash))
    end
  end

  defp send_summary(client, direction, dcdids) do
    if not Enum.empty?(dcdids) do
      dat = {:Summary, direction, Enum.to_list(dcdids)}
      {:ok, encd} = :FloofProtocol.encode(:ProtoMessage, {:summary, dat})
      :gen_tcp.send(client, encd)
    else
      :ok
    end
  end

  defp partition_hashes(xs) do
    xs
    |> Floof.Distributor.have_we_multi()
    |> Enum.to_list()
    |> partition_list(MapSet.new(), MapSet.new())
  end

  defp partition_list([], lo, hi) do
    {lo, hi}
  end

  defp partition_list([{key, cnd} | xs], lo, hi) do
    {lo2, hi2} =
      if cnd do
        {lo, MapSet.put(hi, key)}
      else
        {MapSet.put(lo, key), hi}
      end

    partition_list(xs, lo2, hi2)
  end
end