floof/lib/floof.ex

defmodule Floof do
  @moduledoc """
  Documentation for `Floof`.
  """

  require Logger

  def accept(port, opts \\ []) do
    {:ok, socket} =
      :gen_tcp.listen(
        port,
        [
          :binary,
          packet: 4,
          active: false,
          reuseaddr: true
        ] ++ opts
      )

    try do
      Logger.info("Accepting connections on #{port}")
      loop_acceptor(socket)
    after
      :ok = :gen_tcp.close(socket)
    end
  end

  defp loop_acceptor(socket) do
    {:ok, client} = :gen_tcp.accept(socket)

    {:ok, pid} =
      Task.Supervisor.start_child(Floof.TaskSupervisor, fn ->
        serve(client, %{}, nil)
        :ok = :gen_tcp.close(client)
      end)

    :ok = :gen_tcp.controlling_process(client, pid)
    # switch to active now that we handed over the client
    :inet.setopts(client, [{:active, true}])
    Floof.Distributor.register(pid)
    loop_acceptor(socket)
  end

  def connect(host, port, sesskey \\ nil) do
    {:ok, socket} =
      :gen_tcp.connect(host, port,
        packet: 4,
        active: true
      )

    try do
      Floof.Distributor.register(self())
      Logger.info("Established connection to #{inspect(host)}:#{port}")

      if sesskey != nil do
        {:ok, encd} = :FloofProtocol.encode(:ProtoMessage, {:session, {:attach, sesskey}})
        :ok = :gen_tcp.send(socket, encd)
      end

      serve(socket, %{}, nil)
    after
      :ok = :gen_tcp.close(socket)
    end
  end

  defp serve(client, backlog, sesskey) do
    {backlog, sesskey} =
      receive do
        {:tcp, _, message} ->
          message =
            if :erlang.is_binary(message) do
              message
            else
              :erlang.list_to_binary(message)
            end

          {:ok, dcd} = :FloofProtocol.decode(:ProtoMessage, message)
          backlog = handle_incoming(client, backlog, sesskey, dcd)
          {backlog, sesskey}

        {:fwdxfer, {dcdhash, dcd}} ->
          backlog =
            if sesskey != nil do
              # make sure that stuff gets handled uniformly
              Floof.SessionManager.set_soft(sesskey, dcdhash)
              Floof.PacketSpool.store_new(dcdhash, dcd)
            else
              :ok = send_summary(client, :requestpull, [dcdhash])
              Map.put(backlog, dcdhash, dcd)
            end

          {backlog, sesskey}

        {:SessionPushed, sesskey} ->
          :ok = send_summary(client, :requestpull, Floof.SessionManager.peek(sesskey))
          {backlog, sesskey}

        {:SessionDetached, _} ->
          {backlog, nil}

        {:tcp_closed, _} ->
          # put all the backlogged stuff back if possible
          if sesskey != nil do
            for {dcdhash, dcd} <- backlog do
              Floof.SessionManager.set_soft(sesskey, dcdhash)
              Floof.PacketSpool.store_new(dcdhash, dcd)
            end
            Floof.SessionManager.detach(sesskey, self())
          end

          exit(:normal)

        x ->
          Logger.warn("unable to handle request: #{inspect(x)}")
          {backlog, sesskey}
      end

    serve(client, backlog, sesskey)
  end

  defp handle_incoming(client, backlog, sesskey, dcd) do
    Logger.debug("got packet #{inspect(dcd)}")

    case dcd do
      {:session, {:attach, key}} ->
        Floof.SessionManager.attach(key, self())
        for {dcdhash, dcd} <- backlog do
          Floof.SessionManager.set_soft(sesskey, dcdhash)
          Floof.PacketSpool.store_new(dcdhash, dcd)
        end
        %{}

      {:summary, {:Summary, direction, hashes}} ->
        case direction do
          :requestpull ->
            {to_pull, to_drop} = partition_hashes(hashes)
            :ok = send_summary(client, :pull, to_pull)
            :ok = send_summary(client, :drop, to_drop)
            backlog

          :pull ->
            for mhash <- hashes do
              item =
                case Map.fetch(backlog, mhash) do
                  {:ok, item} -> item
                  :error -> case Floof.PacketSpool.fetch(mhash) do
                    {:ok, item} -> item
                    _ -> nil
                  end
                end

              if item != nil do
                {:ok, encd} = :FloofProtocol.encode(:ProtoMessage, {:xfer, item})
                :ok = :gen_tcp.send(client, encd)
              end
            end

            backlog

          :drop ->
            Floof.SessionManager.drop(sesskey, hashes)
            Map.drop(backlog, hashes)
        end

      {:xfer, xf} ->
        mhash = Floof.Message.emit(xf)
        # notify the remote end that we successfully consumed the message
        # non-fatal if this fails
        send_summary(client, :drop, [mhash])
        backlog
    end
  end

  defp send_summary(client, direction, dcdids) do
    if not Enum.empty?(dcdids) do
      dat = {:Summary, direction, Enum.to_list(dcdids)}
      {:ok, encd} = :FloofProtocol.encode(:ProtoMessage, {:summary, dat})
      :gen_tcp.send(client, encd)
    else
      :ok
    end
  end

  defp partition_hashes(xs) do
    xs
    |> Floof.DistributorSeen.have_we_multi()
    |> Enum.to_list()
    |> partition_list(MapSet.new(), MapSet.new())
  end

  defp partition_list([], lo, hi) do
    {lo, hi}
  end

  defp partition_list([{key, cnd} | xs], lo, hi) do
    {lo2, hi2} =
      if cnd do
        {lo, MapSet.put(hi, key)}
      else
        {MapSet.put(lo, key), hi}
      end

    partition_list(xs, lo2, hi2)
  end
end